List 6-112　Business.SlipコンポーネントのGetSlipメソッド

  1： Public Sub GetSlip(ByVal SlipID As Long, _
   　                    ByRef CUSTOMERID As Variant, _
   　                    ByRef SUBTOTAL As Variant, _
   　                    ByRef TAX As Variant, _
   　                    ByRef TOTAL As Variant, _
   　                    ByRef MADEDATE As Variant, _
   　                    ByRef MADEUSER As Variant, _
   　                    ByRef LASTDATE As Variant, _
   　                    ByRef LASTUSER As Variant)
  2：     ' 伝票情報テーブル内の指定された伝票番号のうち
  3：     ' 基本的な情報を返す
  4：     ' 【引数】
  5：     '   SlipID = 情報を読み出したい伝票を特定する伝票番号を指定する
  6：     '   CUSTOMERID = 指定された伝票の顧客番号が格納される
  7：     '   SUBTOTAL = 指定された伝票の小計が格納される
  8：     '   TAX = 指定された伝票の消費税が格納される
  9：     '   TOTAL = 指定された伝票の合計が格納される
 10：     '   MADEDATE = 指定された伝票の起票日が格納される
 11：     '   MADEUSER = 指定された伝票を起票したユーザーの
 12：     '              アカウント名が格納される
 13：     '   LASTDATE = 指定された伝票の最終更新日時が格納される
 14：     '   LASTUSER = 指定たれさ伝票の最終更新ユーザー名が格納される
 15：     ' 【戻り値】
 16：     '   なし
 17：     Dim objContext As ObjectContext
 18：     Dim objDataSlip As DataObj.Slip
 19：     Dim SlipStatus As DataObj.SlipStatus
 20：     Dim IsDeleted As DataObj.DELETEDFLAG
 21：     
 22：     ' オブジェクトコンテキストの取得
 23：     Set objContext = GetObjectContext()
 24：     
 25：     ' エラーハンドラの設定
 26：     On Error GoTo ErrHandle
 27：     
 28：     ' DataObj.Slipコンポーネントの実体化
 29：     Set objDataSlip = CreateObject("DataObj.Slip")
 30：     
 31：     ' 削除されているかどうかを取得
 32：     IsDeleted = objDataSlip.IsDeleted(SlipID)
 33：     
 34：     ' 伝票の状態を取得
 35：     SlipStatus = objDataSlip.Get_SlipStatus(SlipID)
 36：     
 37：     ' 参照権限があるかどうか
 38：     Chk_View objContext, IsDeleted, SlipStatus
 39：     
 40：     ' 情報を取得してそのまま返す
 41：     objDataSlip.GetRecord_Slip SlipID, CUSTOMERID, _
   　                                SUBTOTAL, TAX, TOTAL, _
   　                                MADEDATE, MADEUSER, _
   　                                LASTDATE, LASTUSER
 42：     
 43：     ' DataObj.Slipコンポーネントの解放
 44：     Set objDataSlip = Nothing
 45：     
 46：     ' トランザクションのコミット
 47：     objContext.SetComplete
 48：     
 49：     ' オブジェクトコンテキストの解放
 50：     Set objContext = Nothing
 51：     
 52：     Exit Sub
 53： 
 54： ErrHandle:
 55：     ' エラーハンドラ
 56：     objContext.SetAbort
 57：     Set objContext = Nothing
 58：     Set objDataSlip = Nothing
 59： 
 60：     ' エラーの再発行
 61：     Err.Raise Err.NUMBER, Err.Source, Err.Description, _
   　    　         Err.HelpFile, Err.HelpContext
 62： End Sub