List 6-117 Business.SlipコンポーネントのGetSlip_Rejectedメソッド
1: Public Sub GetSlip_Rejected(ByVal SlipID As Long, _
ByRef REJECTEDUSER As Variant, _
ByRef REJECTEDDATE As Variant, _
ByRef REJECTEDCOMMENT As Variant)
2: ' 伝票情報テーブル内の指定された伝票番号の伝票のうち
3: ' 却下処理にかかわる情報を返す
4: ' 【引数】
5: ' SlipID = 情報を読み出したい伝票を特定する伝票番号を指定する
6: ' REJECTEDUSER = 却下処理をしたユーザーのアカウント名が格納される
7: ' REJECTEDDATE = 却下処理された日時が格納される
8: ' REJECTEDCOMMENT = 却下処理がされたときのコメントが格納される
9: ' 【戻り値】
10: ' なし
11: Dim objContext As ObjectContext
12: Dim objDataSlip As DataObj.Slip
13: Dim SlipStatus As DataObj.SlipStatus
14: Dim IsDeleted As DataObj.DELETEDFLAG
15:
16: ' オブジェクトコンテキストの取得
17: Set objContext = GetObjectContext()
18:
19: ' エラーハンドラの設定
20: On Error GoTo ErrHandle
21:
22: ' DataObj.Slipコンポーネントの実体化
23: Set objDataSlip = CreateObject("DataObj.Slip")
24:
25: ' 削除されているかどうかを取得
26: IsDeleted = objDataSlip.IsDeleted(SlipID)
27:
28: ' 伝票の状態を取得
29: SlipStatus = objDataSlip.Get_SlipStatus(SlipID)
30:
31: ' 参照権限があるかどうか
32: Chk_View objContext, IsDeleted, SlipStatus
33:
34: ' 情報を取得してそのまま返す
35: objDataSlip.GetRecord_Rejected SlipID, REJECTEDUSER, _
REJECTEDDATE, REJECTEDCOMMENT
36:
37: ' DataObj.Slipコンポーネントの解放
38: Set objDataSlip = Nothing
39:
40: ' トランザクションをコミット
41: objContext.SetComplete
42:
43: ' オブジェクトコンテキストの解放
44: Set objContext = Nothing
45:
46: Exit Sub
47:
48: ErrHandle:
49: ' エラーハンドラ
50: objContext.SetAbort
51: Set objContext = Nothing
52: Set objDataSlip = Nothing
53:
54: ' エラーの再発行
55: Err.Raise Err.NUMBER, Err.Source, Err.Description, _
Err.HelpFile, Err.HelpContext
56: End Sub