List 6-122　Business.SlipコンポーネントのGetSlip_Detailsメソッド

  1： Public Function GetSlip_Details(ByVal SlipID As Long) As ADODB.Recordset
  2：     ' 指定された伝票番号に結び付けられている
  3：     ' 伝票追加情報テーブル中のレコードの一覧（履歴）を
  4：     ' ADODB.Recordsetオブジェクトとして返す
  5：     ' 【引数】
  6：     '   SlipID = 伝票を特定する伝票番号
  7：     ' 【戻り値】
  8：     '   指定された伝票番号に結び付けられた伝票追加情報テーブル中の
  9：     '   レコードを含むADODB.Recordsetオブジェクト
 10：     '   戻り値となるADODB.Recordsetオブジェクトは読み取り専用の閉じたレコードセット
 11：     Dim objContext As ObjectContext
 12：     Dim objDataSlip As DataObj.Slip
 13：     Dim objDataSlipInformation As DataObj.SlipInformation
 14：     Dim SlipStatus As DataObj.SlipStatus
 15：     Dim IsDeleted As DataObj.DELETEDFLAG
 16：     
 17：     ' オブジェクトコンテキストの取得
 18：     Set objContext = GetObjectContext()
 19：     
 20：     ' エラーハンドラの設定
 21：     On Error GoTo ErrHandle
 22： 
 23：     ' DataObj.Slipコンポーネントの実体化
 24：     Set objDataSlip = CreateObject("DataObj.Slip")
 25：     
 26：     ' 削除されているかどうかを取得
 27：     IsDeleted = objDataSlip.IsDeleted(SlipID)
 28：     
 29：     ' 伝票の状態を取得
 30：     SlipStatus = objDataSlip.Get_SlipStatus(SlipID)
 31：     
 32：     ' 参照権限があるかどうか
 33：     Chk_View objContext, IsDeleted, SlipStatus
 34：     
 35：     ' DataObj.SlipInformationコンポーネントの実体化
 36：     Set objDataSlipInformation = CreateObject("DataObj.SlipInformation")
 37：     
 38：     ' 情報を取得してそれを戻り値とする
 39：     Set GetSlip_Details = objDataSlipInformation.GetRecords(SlipID)
 40：     
 41：     ' DataObj.SlipInformationコンポーネントの解放
 42：     Set objDataSlipInformation = Nothing
 43：     ' DataObj.Slipコンポーネントの解放
 44：     Set objDataSlip = Nothing
 45：     
 46：     ' トランザクションをコミット
 47：     objContext.SetComplete
 48：     
 49：     ' オブジェクトコンテキストの解放
 50：     Set objContext = Nothing
 51：     
 52：     Exit Function
 53： 
 54： ErrHandle:
 55：     ' エラーハンドラ
 56：     objContext.SetAbort
 57：     Set objContext = Nothing
 58：     Set objDataSlip = Nothing
 59：     Set objDataSlipInformation = Nothing
 60：     
 61：     Set GetSlip_Details = Nothing
 62：     
 63：     ' エラーの再発行
 64：     Err.Raise Err.NUMBER, Err.Source, Err.Description, _
   　               Err.HelpFile, Err.HelpContext
 65： End Function